> Canonical HTML: https://kerfscript.mylasertools.com/models/ribbed-lantern/

# Ribbed lantern shade

Ribbed lantern shade: curved radial fins locate in two notched rings. Ring tabs are cut into each fin, so changes to thickness update both joints. Assembly: glue the fins into both rings. The shade stands on the fin ends. Shade only: place a separate cool battery LED inside, with no flame.

This design has 18 parts on 3 sheets. Customize it in the [playground](https://kerfscript.mylasertools.com/playground/?model=ribbed-lantern).

## Downloads

- [KerfScript source](https://kerfscript.mylasertools.com/models/ribbed-lantern/ribbed-lantern.kerf)
- [ribbed-lantern-sheet-1.svg](https://kerfscript.mylasertools.com/models/ribbed-lantern/ribbed-lantern-sheet-1.svg)
- [ribbed-lantern-sheet-1.dxf](https://kerfscript.mylasertools.com/models/ribbed-lantern/ribbed-lantern-sheet-1.dxf)
- [ribbed-lantern-sheet-2.svg](https://kerfscript.mylasertools.com/models/ribbed-lantern/ribbed-lantern-sheet-2.svg)
- [ribbed-lantern-sheet-2.dxf](https://kerfscript.mylasertools.com/models/ribbed-lantern/ribbed-lantern-sheet-2.dxf)
- [ribbed-lantern-sheet-3.svg](https://kerfscript.mylasertools.com/models/ribbed-lantern/ribbed-lantern-sheet-3.svg)
- [ribbed-lantern-sheet-3.dxf](https://kerfscript.mylasertools.com/models/ribbed-lantern/ribbed-lantern-sheet-3.dxf)

## Parts

| Part | Quantity | Size |
| --- | ---: | --- |
| Radial fin | 16 | 75 × 200 mm |
| Collar ring | 2 | 105.9 × 105.9 mm |

## Settings

| Name | Default | Range or choices |
| --- | --- | --- |
| `diameter` | `220` | 140 to 340 |
| `height` | `200` | 140 to 300 |
| `ribs` | `16` | 8 to 24 |
| `collar_diameter` | `70` | 50 to 110 |
| `belly` | `1` | 0.6 to 1.8 |
| `$thickness` | `3` | 2 to 6 |
| `$kerf` | `0.15` | 0 to 0.3 |
| `clearance` | `0.15` | 0 to 0.4 |

## Source

```kerf
// Ribbed lantern shade: curved radial fins locate in two notched rings.
// Ring tabs are cut into each fin, so changes to thickness update both joints.
// Assembly: glue the fins into both rings. The shade stands on the fin ends.
// Shade only: place a separate cool battery LED inside, with no flame.

/* [Shade] */
diameter = 220; // [140:5:340]
height = 200; // [140:5:300]
ribs = 16; // [8:1:24]
collar_diameter = 70; // [50:5:110]
belly = 1; // [0.6:0.1:1.8]

/* [Material] */
$thickness = 3; // [2:0.5:6]
$kerf = 0.15; // [0:0.01:0.3]
clearance = 0.15; // [0:0.05:0.4]

/* [Hidden] */
$material = "plywood";
$fn = 128;
t = $thickness;
ri = collar_diameter / 2;
bulge = diameter / 2 - ri - 18;
levels = [20, height - 20];
tab_start = ri + 4;
tab_end = ri + 14;
assert(bulge >= 10, "Increase diameter or reduce the collar");
assert(2 * (ri + 4) * sin(180 / ribs) > t + clearance + 4, "Reduce ribs or increase the collar diameter");
function outer(z) = ri + 18 + bulge * pow(sin(180 * z / height), belly);
module fin() difference() {
  polygon(concat([[ri, 0]], [for (i = [0:60]) [outer(height * i / 60), height * i / 60]], [[ri, height]]));
  for (z = levels) {
    translate([ri - 1, z - clearance / 2]) rect([tab_start - ri + 1, t + clearance]);
    translate([tab_end, z - clearance / 2]) rect([diameter, t + clearance]);
  }
}
step("Set the fins out in a circle, tabs facing in")
  part("Radial fin", qty = ribs,
    at = [for (i = [0:ribs - 1]) [-t / 2 * sin(360 * i / ribs), t / 2 * cos(360 * i / ribs), 0]],
    rotate = [for (i = [0:ribs - 1]) [90, 0, 360 * i / ribs]]) fin();
step("Slide the fin tabs into both collar rings and glue them")
  part("Collar ring", qty = 2, at = [for (z = levels) [0, 0, z]]) difference() {
    circle(r = ri + 18);
    circle(r = ri - 5);
    // Open each slot through the outside rim so fins can slide in radially.
    for (i = [0:ribs - 1]) rotate(360 * i / ribs) translate([tab_start - clearance / 2, -(t + clearance) / 2])
      rect([ri + 19 - tab_start + clearance, t + clearance]);
  }
```

Set power, speed and cut order in your laser software. See the [laser software guide](https://kerfscript.mylasertools.com/docs/compatibility/index.md).
