> Canonical HTML: https://kerfscript.mylasertools.com/models/pocket-valet/

# Pocket valet tray

Pocket valet: a shallow tray with a removable key and watch perch. A tabbed upright holds a horizontal shelf with open key-ring notches. Assembly: glue the tray and upright joints; add felt if desired.

This design has 7 parts on 1 sheet. Customize it in the [playground](https://kerfscript.mylasertools.com/playground/?model=pocket-valet).

## Downloads

- [KerfScript source](https://kerfscript.mylasertools.com/models/pocket-valet/pocket-valet.kerf)
- [SVG](https://kerfscript.mylasertools.com/models/pocket-valet/pocket-valet.svg)
- [DXF](https://kerfscript.mylasertools.com/models/pocket-valet/pocket-valet.dxf)

## Parts

| Part | Quantity | Size |
| --- | ---: | --- |
| Floor | 1 | 220 × 140 mm |
| Long wall | 2 | 220 × 28 mm |
| End wall | 2 | 140 × 28 mm |
| Perch upright | 1 | 196 × 123 mm |
| Key perch | 1 | 196 × 31 mm |

## Settings

| Name | Default | Range or choices |
| --- | --- | --- |
| `width` | `220` | 150 to 320 |
| `depth` | `140` | 100 to 220 |
| `tray_height` | `28` | 20 to 45 |
| `perch_height` | `110` | 80 to 160 |
| `keys` | `4` | 2 to 7 |
| `$thickness` | `3` | 2 to 6 |
| `$kerf` | `0.15` | 0 to 0.3 |
| `clearance` | `0.15` | 0 to 0.4 |

## Source

```kerf
// Pocket valet: a shallow tray with a removable key and watch perch.
// A tabbed upright holds a horizontal shelf with open key-ring notches.
// Assembly: glue the tray and upright joints; add felt if desired.

use <kerf/tabs>

/* [Valet] */
width = 220; // [150:5:320]
depth = 140; // [100:5:220]
tray_height = 28; // [20:2:45]
perch_height = 110; // [80:5:160]
keys = 4; // [2:1:7]

/* [Material] */
$thickness = 3; // [2:0.5:6]
$kerf = 0.15; // [0:0.01:0.3]
clearance = 0.15; // [0:0.05:0.4]

/* [Hidden] */
$material = "plywood";
t = $thickness;
span = width - 24;
wall_at = depth - 24;
reach = 28;
step("Glue the walls into the floor") {
  part("Floor", at = [0, 0, 0]) difference() {
    finger_rect([width, depth], "out");
    translate([12, wall_at]) slots(span, clearance = clearance);
  }
  part("Long wall", qty = 2, at = [[0, t, 0], [0, depth, 0]], rotate = [90, 0, 0]) finger_rect([width, tray_height], ["in", "out", "flat", "out"]);
  part("End wall", qty = 2, at = [[0, 0, 0], [width - t, 0, 0]], rotate = [90, 0, 90]) finger_rect([depth, tray_height], ["in", "in", "flat", "in"]);
}
step("Glue the upright into the floor")
  part("Perch upright", at = [12, wall_at + t / 2, t], rotate = [90, 0, 0]) difference() {
    union() { rect([span, perch_height + 10], r = 3); tabs(span); }
    translate([0, perch_height + t / 2]) slots(span, clearance = clearance);
  }
step("Glue the key perch into the upright")
  part("Key perch", at = [12, wall_at - t / 2 - reach, t + perch_height]) difference() {
    tab_rect([span, reach], [false, false, true, false]);
    for (i = [0:keys - 1]) translate([span * (i + 0.5) / keys, 0]) rect([5, 18], center = true, r = 2);
  }
// Rear-edge tabs pass through the upright into free space behind it.
```

Set power, speed and cut order in your laser software. See the [laser software guide](https://kerfscript.mylasertools.com/docs/compatibility/index.md).
