> Canonical HTML: https://kerfscript.mylasertools.com/models/jewel-tray-box/

# Jewellery tray box

Jewel tray box: an open box, lift-off lid and removable compartment grid. The lid locates on a glued inset plate; it is not a friction-fit hinge. Assembly: glue the box joints and lid layers. Leave the grid removable.

This design has 11 parts on 2 sheets. Customize it in the [playground](https://kerfscript.mylasertools.com/playground/?model=jewel-tray-box).

## Downloads

- [KerfScript source](https://kerfscript.mylasertools.com/models/jewel-tray-box/jewel-tray-box.kerf)
- [jewel-tray-box-sheet-1.svg](https://kerfscript.mylasertools.com/models/jewel-tray-box/jewel-tray-box-sheet-1.svg)
- [jewel-tray-box-sheet-1.dxf](https://kerfscript.mylasertools.com/models/jewel-tray-box/jewel-tray-box-sheet-1.dxf)
- [jewel-tray-box-sheet-2.svg](https://kerfscript.mylasertools.com/models/jewel-tray-box/jewel-tray-box-sheet-2.svg)
- [jewel-tray-box-sheet-2.dxf](https://kerfscript.mylasertools.com/models/jewel-tray-box/jewel-tray-box-sheet-2.dxf)

## Parts

| Part | Quantity | Size |
| --- | ---: | --- |
| bottom | 1 | 210 × 145 mm |
| front | 1 | 210 × 55 mm |
| back | 1 | 210 × 55 mm |
| left | 1 | 145 × 55 mm |
| right | 1 | 145 × 55 mm |
| long divider | 1 | 203 × 42 mm |
| cross divider | 3 | 138 × 42 mm |
| Lid | 1 | 218 × 153 mm |
| Lid locator | 1 | 202.6 × 137.6 mm |

## Settings

| Name | Default | Range or choices |
| --- | --- | --- |
| `width` | `210` | 100 to 320 |
| `depth` | `145` | 80 to 240 |
| `height` | `55` | 35 to 100 |
| `columns` | `4` | 1 to 7 |
| `rows` | `2` | 1 to 5 |
| `lid_overhang` | `4` | 2 to 8 |
| `lid_ease` | `0.7` | 0.4 to 1.5 |
| `lid_lift` | `45` | 0 to 100 |
| `$thickness` | `3` | 2 to 6 |
| `$kerf` | `0.15` | 0 to 0.3 |
| `clearance` | `0.15` | 0 to 0.4 |

## Source

```kerf
// Jewel tray box: an open box, lift-off lid and removable compartment grid.
// The lid locates on a glued inset plate; it is not a friction-fit hinge.
// Assembly: glue the box joints and lid layers. Leave the grid removable.

use <kerf/box>
use <kerf/dividers>

/* [Box] */
width = 210; // [100:5:320]
depth = 145; // [80:5:240]
height = 55; // [35:5:100]
columns = 4; // [1:1:7]
rows = 2; // [1:1:5]
lid_overhang = 4; // [2:1:8]
lid_ease = 0.7; // [0.4:0.1:1.5]

/* [Assembled view] */
// Lift the lid to see the compartments. Cut parts keep their dimensions.
lid_lift = 45; // [0:5:100]

/* [Material] */
$thickness = 3; // [2:0.5:6]
$kerf = 0.15; // [0:0.01:0.3]
clearance = 0.15; // [0:0.05:0.4]

/* [Hidden] */
$material = "plywood";
t = $thickness;
iw = width - 2 * t;
id = depth - 2 * t;
assert(iw / columns > 18 && id / rows > 18, "Compartments must be wider than 18 mm");
assert(height > 5 * t + 8, "Increase height for the lid locator and dividers");
step("Glue the box together") box([width, depth, height]);
step("Drop the compartment grid in, without glue") grid_dividers([iw, id, height - 3 * t - 4], columns, rows, clearance = clearance, scoops = true, at = [t, t, t]);
step("Glue the lid locator under the lid") {
  part("Lid", at = [-lid_overhang, -lid_overhang, height + lid_lift]) {
    rect([width + 2 * lid_overhang, depth + 2 * lid_overhang], r = 5);
    score() translate([lid_overhang + width / 2, lid_overhang + depth / 2]) {
      outline() rect([width * 0.6, depth * 0.54], center = true, r = 8);
      for (x = [-width * 0.18, 0, width * 0.18]) translate([x, 0]) outline() circle(d = 10);
    }
  }
  part("Lid locator", at = [t + lid_ease, t + lid_ease, height - t + lid_lift])
    rect([iw - 2 * lid_ease, id - 2 * lid_ease], r = 3);
}
```

Set power, speed and cut order in your laser software. See the [laser software guide](https://kerfscript.mylasertools.com/docs/compatibility/index.md).
