// Drawer organizer: a finger-jointed tray from the box library, and a grid
// of dividers from the dividers library that slot into each other like an
// egg crate. Measure your drawer, then pick how many compartments you want.

use <kerf/box>
use <kerf/dividers>

/* [Tray] */
// Outside width
width = 240; // [80:5:560]
// Outside depth, front to back
depth = 160; // [60:5:380]
// Outside height
height = 50; // [25:5:120]

/* [Compartments] */
// Compartments across
cols = 4; // [1:1:10]
// Compartments front to back
rows = 2; // [1:1:8]
// Dips in the divider tops, to reach in with a finger
scoops = true;

/* [Material] */
// Sheet thickness
$thickness = 3; // [2:0.5:6]
// Beam width
$kerf = 0.15; // [0:0.01:0.3]
// Added to every slot, for an easy fit
clearance = 0.15; // [0:0.05:0.4]

/* [Hidden] */
$material = "plywood";
t = $thickness;

box([width, depth, height]);

// Inside the tray, standing on its floor, a little lower than the walls
grid_dividers([width - 2 * t, depth - 2 * t, height - t - 2], cols, rows,
  clearance = clearance, scoops = scoops, at = [t, t, t]);