> Canonical HTML: https://kerfscript.mylasertools.com/models/cantilever-case/

# Cantilever sewing and tool case

Cantilever case: two banks of trays rise outward on parallel pivot links. The pivot offsets and link lengths are computed from the tray dimensions. Assembly: glue the base and each tray square. Bolt the links outside the front and back walls, using washers and standoffs to separate link layers. Link pivots must turn freely. Do not glue the links to the trays.

This design has 41 parts on 2 sheets. Customize it in the [playground](https://kerfscript.mylasertools.com/playground/?model=cantilever-case).

## Downloads

- [KerfScript source](https://kerfscript.mylasertools.com/models/cantilever-case/cantilever-case.kerf)
- [cantilever-case-sheet-1.svg](https://kerfscript.mylasertools.com/models/cantilever-case/cantilever-case-sheet-1.svg)
- [cantilever-case-sheet-1.dxf](https://kerfscript.mylasertools.com/models/cantilever-case/cantilever-case-sheet-1.dxf)
- [cantilever-case-sheet-2.svg](https://kerfscript.mylasertools.com/models/cantilever-case/cantilever-case-sheet-2.svg)
- [cantilever-case-sheet-2.dxf](https://kerfscript.mylasertools.com/models/cantilever-case/cantilever-case-sheet-2.dxf)

## Parts

| Part | Quantity | Size |
| --- | ---: | --- |
| Base well floor | 1 | 226 × 140 mm |
| Base well front | 1 | 226 × 44 mm |
| Base well back | 1 | 226 × 44 mm |
| Base well end | 2 | 140 × 44 mm |
| Left tray 1 floor | 1 | 110 × 140 mm |
| Left tray 1 front | 1 | 110 × 32 mm |
| Left tray 1 back | 1 | 110 × 32 mm |
| Left tray 1 end | 2 | 140 × 32 mm |
| Left link 1 front 1 | 1 | 70.5 × 9 mm |
| Left link 1 front 2 | 1 | 70.5 × 9 mm |
| Left link 1 back 1 | 1 | 70.5 × 9 mm |
| Left link 1 back 2 | 1 | 70.5 × 9 mm |
| Left tray 2 floor | 1 | 110 × 140 mm |
| Left tray 2 front | 1 | 110 × 32 mm |
| Left tray 2 back | 1 | 110 × 32 mm |
| Left tray 2 end | 2 | 140 × 32 mm |
| Left link 2 front 1 | 1 | 70.5 × 9 mm |
| Left link 2 front 2 | 1 | 70.5 × 9 mm |
| Left link 2 back 1 | 1 | 70.5 × 9 mm |
| Left link 2 back 2 | 1 | 70.5 × 9 mm |
| Right tray 1 floor | 1 | 110 × 140 mm |
| Right tray 1 front | 1 | 110 × 32 mm |
| Right tray 1 back | 1 | 110 × 32 mm |
| Right tray 1 end | 2 | 140 × 32 mm |
| Right link 1 front 1 | 1 | 70.5 × 9 mm |
| Right link 1 front 2 | 1 | 70.5 × 9 mm |
| Right link 1 back 1 | 1 | 70.5 × 9 mm |
| Right link 1 back 2 | 1 | 70.5 × 9 mm |
| Right tray 2 floor | 1 | 110 × 140 mm |
| Right tray 2 front | 1 | 110 × 32 mm |
| Right tray 2 back | 1 | 110 × 32 mm |
| Right tray 2 end | 2 | 140 × 32 mm |
| Right link 2 front 1 | 1 | 70.5 × 9 mm |
| Right link 2 front 2 | 1 | 70.5 × 9 mm |
| Right link 2 back 1 | 1 | 70.5 × 9 mm |
| Right link 2 back 2 | 1 | 70.5 × 9 mm |

## Settings

| Name | Default | Range or choices |
| --- | --- | --- |
| `tray_width` | `110` | 90 to 170 |
| `depth` | `140` | 100 to 220 |
| `tray_height` | `32` | 25 to 50 |
| `base_height` | `44` | 35 to 75 |
| `levels` | `2` | 1 to 3 |
| `lids` | `false` | on or off |
| `opening` | `0.8` | 0 to 1 |
| `$thickness` | `3` | 2 to 6 |
| `$kerf` | `0.15` | 0 to 0.3 |
| `pin_diameter` | `3` | 3 to 4 |
| `pivot_clearance` | `0.3` | 0.2 to 0.6 |
| `washer_gap` | `0.5` | 0.3 to 1 |

## Source

```kerf
// Cantilever case: two banks of trays rise outward on parallel pivot links.
// The pivot offsets and link lengths are computed from the tray dimensions.
// Assembly: glue the base and each tray square. Bolt the links outside the
// front and back walls, using washers and standoffs to separate link layers.
// Link pivots must turn freely. Do not glue the links to the trays.

/* [Storage] */
tray_width = 110; // [90:5:170]
depth = 140; // [100:5:220]
tray_height = 32; // [25:1:50]
base_height = 44; // [35:1:75]
levels = 2; // [1:1:3]
lids = false;

/* [Assembled view] */
// Zero closes the trays; one raises them to the designed open position.
opening = 0.8; // [0:0.05:1]

/* [Material] */
$thickness = 3; // [2:0.5:6]
$kerf = 0.15; // [0:0.01:0.3]
pin_diameter = 3; // [3:0.5:4]
pivot_clearance = 0.3; // [0.2:0.05:0.6]
washer_gap = 0.5; // [0.3:0.1:1]

/* [Hidden] */
$material = "plywood";
t = $thickness;
seam = 6;
base_w = 2 * tray_width + seam;
step = tray_height + 3;
offset = tray_width * 0.46;
spread = tray_width * 0.24;
margin = tray_width * 0.10;
link_length = sqrt(offset * offset + step * step);
closed_angle = atan2(step, offset);
angle = closed_angle + (82 - closed_angle) * opening;
dx = offset - link_length * cos(angle);
dz = link_length * sin(angle);
arm_width = max(9, 2 * t + 3);
assert(spread * sin(closed_angle) > arm_width + 0.5, "Increase tray height or width, or use thinner stock, to separate the parallel links");
assert(base_height - tray_height / 2 > t + pin_diameter + 3, "Increase the base height to support its pivot holes");
assert(tray_height / 2 > t + pin_diameter + 2, "Increase tray height for this sheet and pivot size");
assert(margin > pin_diameter / 2 + 3, "Pivot margin is too small");
function anchor(side, k, upper = false) = margin + k * spread + ((side > 0 ? !upper : upper) ? offset : 0);
function tray_at(side, j) = [(side < 0 ? 0 : tray_width + seam) + side * j * dx, 0,
  base_height - tray_height / 2 + j * dz - tray_height / 2];
function pivot(side, j, k, upper = false) = tray_at(side, j) + [anchor(side, k, upper), 0, tray_height / 2];
module pivot_holes(side, base = false, stage = 0) {
  // Base walls support outgoing links only; top trays receive incoming links.
  // Intermediate trays connect both stages.
  for (k = [0:1], upper = base ? [false] : (stage == levels ? [true] : [false, true]))
    translate([anchor(side, k, upper), base ? base_height - tray_height / 2 : tray_height / 2]) circle(d = pin_diameter + pivot_clearance);
}
module tray(name, w, h, at, side = 0, stage = 0) {
  part(str(name, " floor"), at = at) finger_rect([w, depth], "out");
  for (back = [false, true]) part(str(name, back ? " back" : " front"), at = at + [0, back ? depth : t, 0], rotate = [90, 0, 0]) difference() {
    finger_rect([w, h], ["in", "out", "flat", "out"]);
    if (side == 0) for (s = [-1, 1]) translate([s < 0 ? 0 : tray_width + seam, 0]) pivot_holes(s, true);
    else pivot_holes(side, stage = stage);
  }
  part(str(name, " end"), qty = 2, at = [at, at + [w - t, 0, 0]], rotate = [90, 0, 90]) finger_rect([depth, h], ["in", "in", "flat", "in"]);
}
module link() difference() {
  hull() { circle(d = arm_width); translate([link_length, 0]) circle(d = arm_width); }
  for (x = [0, link_length]) translate([x, 0]) circle(d = pin_diameter + pivot_clearance);
}
step("Glue up the base well") tray("Base well", base_w, base_height, [0, 0, 0]);
for (side = [-1, 1], j = [1:levels]) {
  tag = str(side < 0 ? "Left" : "Right", " tray ", j);
  step(str("Glue up the level ", j, " trays and bolt their links on outside the front and back walls")) {
    tray(tag, tray_width, tray_height, tray_at(side, j), side, j);
    for (back = [false, true], k = [0:1]) {
      y = back ? depth + washer_gap + t + (j - 1) * (t + washer_gap) : -washer_gap - (j - 1) * (t + washer_gap);
      part(str(side < 0 ? "Left" : "Right", " link ", j, back ? " back " : " front ", k + 1),
        at = pivot(side, j - 1, k) + [0, y, 0], rotate = [90, -(side < 0 ? angle : 180 - angle), 0]) link();
    }
  }
  if (lids && j == levels) step("Glue a locator under each lid and set the lids on the top trays") {
    at = tray_at(side, j);
    part(str(tag, " lid"), at = at + [-2, -2, tray_height]) rect([tray_width + 4, depth + 4], r = 3);
    part(str(tag, " lid locator"), at = at + [t + 0.7, t + 0.7, tray_height - t]) rect([tray_width - 2 * t - 1.4, depth - 2 * t - 1.4], r = 2);
  }
}
```

Set power, speed and cut order in your laser software. See the [laser software guide](https://kerfscript.mylasertools.com/docs/compatibility/index.md).
