> Canonical HTML: https://kerfscript.mylasertools.com/models/cable-harbour/

# Cable harbour device tray

Cable harbour: a divided device tray with cable exits through its back. Bay width, count and cable diameter generate the internal layout. Assembly: glue the box, then fit the dividers without glue for cleaning.

This design has 7 parts on 1 sheet. Customize it in the [playground](https://kerfscript.mylasertools.com/playground/?model=cable-harbour).

## Downloads

- [KerfScript source](https://kerfscript.mylasertools.com/models/cable-harbour/cable-harbour.kerf)
- [SVG](https://kerfscript.mylasertools.com/models/cable-harbour/cable-harbour.svg)
- [DXF](https://kerfscript.mylasertools.com/models/cable-harbour/cable-harbour.dxf)

## Parts

| Part | Quantity | Size |
| --- | ---: | --- |
| Floor | 1 | 93 × 145 mm |
| Front | 1 | 93 × 44 mm |
| Cable wall | 1 | 93 × 44 mm |
| End | 2 | 145 × 44 mm |
| Device divider | 2 | 138 × 68 mm |

## Settings

| Name | Default | Range or choices |
| --- | --- | --- |
| `bays` | `3` | 1 to 6 |
| `bay_width` | `27` | 20 to 45 |
| `depth` | `145` | 90 to 230 |
| `wall_height` | `44` | 30 to 70 |
| `divider_height` | `65` | 45 to 100 |
| `cable_diameter` | `8` | 5 to 14 |
| `$thickness` | `3` | 2 to 6 |
| `$kerf` | `0.15` | 0 to 0.3 |
| `clearance` | `0.15` | 0 to 0.4 |

## Source

```kerf
// Cable harbour: a divided device tray with cable exits through its back.
// Bay width, count and cable diameter generate the internal layout.
// Assembly: glue the box, then fit the dividers without glue for cleaning.

use <kerf/dividers>
use <kerf/tabs>

/* [Devices] */
bays = 3; // [1:1:6]
bay_width = 27; // [20:1:45]
depth = 145; // [90:5:230]
wall_height = 44; // [30:2:70]
divider_height = 65; // [45:5:100]
cable_diameter = 8; // [5:1:14]

/* [Material] */
$thickness = 3; // [2:0.5:6]
$kerf = 0.15; // [0:0.01:0.3]
clearance = 0.15; // [0:0.05:0.4]

/* [Hidden] */
$material = "plywood";
t = $thickness;
w = bays * bay_width + (bays + 1) * t;
part("Floor", at = [0, 0, 0]) difference() {
  finger_rect([w, depth], "out");
  if (bays > 1) for (i = [1:bays - 1]) translate([i * (bay_width + t) + t / 2, t + 0.5]) rotate(90)
    slots(depth - 2 * t - 1, clearance = clearance);
}
step("Glue the front, the cable wall and the ends to the floor") {
  part("Front", at = [0, t, 0], rotate = [90, 0, 0]) finger_rect([w, wall_height], ["in", "out", "flat", "out"]);
  part("Cable wall", at = [0, depth, 0], rotate = [90, 0, 0]) difference() {
    finger_rect([w, wall_height], ["in", "out", "flat", "out"]);
    for (i = [0:bays - 1]) translate([t + bay_width / 2 + i * (bay_width + t), wall_height])
      rect([cable_diameter, wall_height * 0.66], center = true, r = cable_diameter / 2);
  }
  part("End", qty = 2, at = [[0, 0, 0], [w - t, 0, 0]], rotate = [90, 0, 90])
    finger_rect([depth, wall_height], ["in", "in", "flat", "in"]);
}
step("Fit the device dividers into the floor slots, without glue")
  if (bays > 1) part("Device divider", qty = bays - 1,
    at = [for (i = [1:bays - 1]) [i * (bay_width + t), t + 0.5, t]], rotate = [90, 0, 90])
    union() { rect([depth - 2 * t - 1, divider_height], r = 4); tabs(depth - 2 * t - 1); }
```

Set power, speed and cut order in your laser software. See the [laser software guide](https://kerfscript.mylasertools.com/docs/compatibility/index.md).
