> Canonical HTML: https://kerfscript.mylasertools.com/models/book-brace/

# Book brace pair

Book brace: a bookend pair with tabbed uprights and triangular gussets. The foot extends beneath the books so their weight helps stabilize it. Assembly: glue each upright and gusset into its foot. Add non-slip pads.

This design has 6 parts on 1 sheet. Customize it in the [playground](https://kerfscript.mylasertools.com/playground/?model=book-brace).

## Downloads

- [KerfScript source](https://kerfscript.mylasertools.com/models/book-brace/book-brace.kerf)
- [SVG](https://kerfscript.mylasertools.com/models/book-brace/book-brace.svg)
- [DXF](https://kerfscript.mylasertools.com/models/book-brace/book-brace.dxf)

## Parts

| Part | Quantity | Size |
| --- | ---: | --- |
| Foot 1 | 1 | 110 × 120 mm |
| Upright 1 | 1 | 98 × 158 mm |
| Gusset 1 | 1 | 96 × 83 mm |
| Foot 2 | 1 | 110 × 120 mm |
| Upright 2 | 1 | 98 × 158 mm |
| Gusset 2 | 1 | 96 × 83 mm |

## Settings

| Name | Default | Range or choices |
| --- | --- | --- |
| `height` | `155` | 100 to 230 |
| `width` | `110` | 80 to 180 |
| `foot_length` | `120` | 90 to 190 |
| `brace_height` | `80` | 50 to 100 |
| `$thickness` | `3` | 2 to 6 |
| `$kerf` | `0.15` | 0 to 0.3 |
| `clearance` | `0.15` | 0 to 0.4 |

## Source

```kerf
// Book brace: a bookend pair with tabbed uprights and triangular gussets.
// The foot extends beneath the books so their weight helps stabilize it.
// Assembly: glue each upright and gusset into its foot. Add non-slip pads.

use <kerf/tabs>

/* [Bookends] */
height = 155; // [100:5:230]
width = 110; // [80:5:180]
foot_length = 120; // [90:5:190]
brace_height = 80; // [50:5:100]

/* [Material] */
$thickness = 3; // [2:0.5:6]
$kerf = 0.15; // [0:0.01:0.3]
clearance = 0.15; // [0:0.05:0.4]

/* [Hidden] */
$material = "plywood";
t = $thickness;
assert(brace_height < height - 12, "Gusset must be lower than the upright");
for (k = [0:1]) {
  ox = k * (width + 28);
  part(str("Foot ", k + 1), at = [ox, 0, 0]) difference() {
    rect([width, foot_length], r = 3);
    translate([6, 10 + t / 2]) slots(width - 12, clearance = clearance);
    translate([width / 2, 10 + t]) rotate(90) slots(foot_length - 24, count = 2, clearance = clearance);
  }
  step("Glue each upright into its foot")
    part(str("Upright ", k + 1), at = [ox + 6, 10 + t, t], rotate = [90, 0, 0])
      union() { rect([width - 12, height], r = 4); tabs(width - 12); }
  step("Glue a gusset into each foot, behind its upright")
    part(str("Gusset ", k + 1), at = [ox + width / 2 - t / 2, 10 + t, t], rotate = [90, 0, 90])
      union() {
        polygon([[0, 0], [foot_length - 24, 0], [0, brace_height]]);
        tabs(foot_length - 24, count = 2);
      }
}
```

Set power, speed and cut order in your laser software. See the [laser software guide](https://kerfscript.mylasertools.com/docs/compatibility/index.md).
